home *** CD-ROM | disk | FTP | other *** search
/ Magnum One / Magnum One (Mid-American Digital) (Disc Manufacturing).iso / d27 / dspjbl.arc / DSPJBLR.RPG < prev    next >
Encoding:
Text File  |  1991-12-04  |  4.3 KB  |  115 lines
  1.      F*DESCRIPTION  DISPLAY JOB LIST
  2.      F*PROGRAMMER   DAVID EDLEN
  3.      F*
  4.      FDSPJBLD CF  E                    WORKSTN
  5.      F                                        JOBRRNKSFILE JOBLIST
  6.      E                    JOB        50 26  D
  7.      IJOBDS       DS
  8.      I                                        1  10 JOBNAM
  9.      I                                       11  20 JOBUSR
  10.      I                                       21  26 JOBNBR
  11.      I           SDS
  12.      I                                     *PROGRAM PGM$
  13.      C/SPACE
  14.      C** PARAMETER LIST
  15.      C/SPACE
  16.      C           *ENTRY    PLIST
  17.      C                     PARM           JOB$   10
  18.      C                     PARM           USR$   10
  19.      C                     PARM           NBR$    6
  20.      C                     PARM           OPTION  1
  21.      C                     PARM           PRVPGM
  22.      C/SPACE
  23.      C** RETRIEVE THE JOB LIST FROM THE DATE QUEUE AND BUILD THE SUBFILE.
  24.      C/SPACE
  25.      C           OPTION    IFEQ '0'
  26.      C                     Z-ADD0         N       40
  27.      C                     MOVE *BLANK    JOB
  28.      C*
  29.      C           *IN99     DOUEQ'1'
  30.      C                     CALL 'QRCVDTAQ'
  31.      C                     PARM '@JOBLIST'QNAME  10
  32.      C                     PARM 'QTEMP'   QLIB   10
  33.      C                     PARM 26        FLDLEN  50
  34.      C                     PARM *BLANK    DATA   26
  35.      C                     PARM 0         WAIT    50
  36.      C           FLDLEN    IFEQ 0
  37.      C                     MOVE '1'       *IN99
  38.      C                     ELSE
  39.      C                     MOVE '0'       *IN99
  40.      C                     ADD  1         N
  41.      C                     MOVELDATA      JOB,N
  42.      C                     END
  43.      C                     END
  44.      C*
  45.      C                     SORTAJOB
  46.      C                     MOVE '1'       *IN50
  47.      C                     WRITEJOBDSPLY
  48.      C                     MOVE '0'       *IN50
  49.      C                     Z-ADD0         JOBRRN  40
  50.      C                     Z-ADD1         DSPREC
  51.      C*
  52.      C           1         DO   N         J       40
  53.      C                     ADD  1         JOBRRN
  54.      C                     MOVELJOB,J     JOBDS
  55.      C                     WRITEJOBLIST
  56.      C                     END
  57.      C*
  58.      C           JOBRRN    COMP 0                      5151
  59.      C                     END
  60.      C/SPACE
  61.      C** DISPLAY THE JOB LIST; GET NEXT OPTION FROM THE OPERATOR.
  62.      C/SPACE
  63.      C                     WRITEMSGCTL
  64.      C                     WRITEINSTRUCT
  65.      C*
  66.      C           DSPLY     TAG                             *** DSPLY ***
  67.      C                     EXFMTJOBDSPLY
  68.      C*
  69.      C           *INKA     IFEQ '1'
  70.      C           *INKB     OREQ '1'
  71.      C                     MOVE '9'       OPTION
  72.      C                     END
  73.      C*
  74.      C           *INKE     IFEQ '1'
  75.      C                     MOVE '5'       OPTION
  76.      C                     END
  77.      C*
  78.      C           OPTION    CABGE'5'       ENDPGM
  79.      C/SPACE
  80.      C** READ THE SUBFILE FOR SELECTIONS.
  81.      C/SPACE
  82.      C                     MOVE '0'       STOP    1
  83.      C                     MOVE *BLANK    OPTION
  84.      C*
  85.      C           *IN99     DOUEQ'1'
  86.      C                     READCJOBLIST                  99
  87.      C           *IN99     IFEQ '0'
  88.      C           STOP      IFEQ '0'
  89.      C           SELECT    ANDNE*BLANK
  90.      C                     MOVE JOBNAM    JOB$
  91.      C                     MOVE JOBUSR    USR$
  92.      C                     MOVE JOBNBR    NBR$
  93.      C                     MOVE SELECT    OPTION
  94.      C                     MOVE '1'       STOP
  95.      C                     Z-ADDJOBRRN    DSPREC
  96.      C                     END
  97.      C                     MOVE *BLANK    SELECT
  98.      C                     UPDATJOBLIST
  99.      C                     END
  100.      C                     END
  101.      C*
  102.      C           OPTION    IFEQ *BLANK
  103.      C                     MOVE '9'       OPTION
  104.      C                     END
  105.      C/SPACE
  106.      C** END OF PROGRAM
  107.      C/SPACE
  108.      C           ENDPGM    TAG                             *** ENDPGM ***
  109.      C*
  110.      C           OPTION    IFEQ '9'
  111.      C                     MOVE '1'       *INLR
  112.      C                     END
  113.      C*
  114.      C                     RETRN
  115.